From: alex@BibServer.Physik.Uni-Mainz.DE (Alexander Frink)
Subject: Re: simplifying nested radicals
Date: Thu, 6 Jan 2000 20:00:08 +0100
X-Original-Newsgroups: sci.math.symbolic
To: rusin@vesuvius.math.niu.edu (Dave Rusin)
Summary: parameterizing a rational surface

Dear Dave,

In article <84rc8t$aeo$1@gannett.math.niu.edu>,
	rusin@vesuvius.math.niu.edu (Dave Rusin) writes:
> Define  k, l  to be the square roots of  (x+y-2)/(x+y+2)  and  (x-y-2)/(x-y+2)
> respectively. (In your case,  k=2/3 and l=1/sqrt(11)  will do.)

thanks a lot for your help. I have just one more question:
Is there something like an algorithm to find such a substitution
or is this an educated guess? Do you have any literature links?

I try to generalize it to a case where I need

(x+y+m1+m2)*(x+y+m1-m2)*(x+y-m1+m2)*(x+y-m1-m2)*
(x^2-y^2+2*(x+y)*m3+m2^2-m1^2)*(x^2-y^2-2*(x+y)*m3+m2^2-m1^2)

to be a square after the substitution (m1=m2=m3 is related to the
case I posted before). I found one for the case that m1=m2:

mysubs:=solve({k^2=(x+y-2*m1)/(x+y+2*m1), l^2=(x-y-2*m3)/(x-y+2*m3)}, {x,y});

but I failed for the general case. So, before I start an exhaustive
search, I would like to know if there is a smarter approach.

Thanks in advance,

Alex
-- 
Alexander Frink, Institut fuer Physik, Johannes-Gutenberg-Universitaet
D-55099 Mainz, Germany, Phone:  +49-6131-3923391.

==============================================================================
From: Dave Rusin <rusin@math.niu.edu>
Subject: Re: simplifying nested radicals
Date: Thu, 6 Jan 2000 14:02:18 -0600 (CST)
To: alex@BibServer.Physik.Uni-Mainz.DE

No, there is no automatic way to do these things. I must confess that before
I posted my previous response, I went through a long, roundabout set of
substitutions which, only after I saw the net effect, I eventually saw could
be made simple.

There is a fundamental problem here: you are giving polynomials  F(x,y)
and asking for parameterizations  x=x(u,v), y=y(u,v)  which make
F(x(u,v),y(u,v)) be identically a square. I'm convinced that this is the
right thing to do in your case (notwithstanding some noble but confused
posts by someone else). The problem is that the surface  z^2=F(x,y)  in
R^3  may not be "rational" at all, that is, there may be no rational
functions  x,y,z  of  u,v  which make this equation identically true.
This is perhaps better known in the simpler case  z^2=F(x), with  F  an
irreducible cubic polynomial: this equation describes an "elliptic curve"
in the plane, which cannot be parameterized by rational functions.

So what we would hope for is that for each choice of  m1,  m2, m3  your
equation  F(x,y)=z^2  describes a _rational_ surface in R^3. That might be
true, but it's not immediately clear how to check it. Moreover, it's
not obvious that we have an effective procedure to parameterize surfaces
even when they _are_ known to be rational! 

Having said all this, I can nonethless handle the general problem for you.
We can capitalize on the symmetry of  F  by rewriting it in terms of
S=x+y  and  T=x-y.  Then we have an expression which we hope to make square,
which we realize is only a _quadratic_ polynomial in  T. This is good: the
equation  z^2=F(x,y)  is then, for each fixed value of  S,  a quadratic
equation in two variables  z  and  S. These surfaces can _always_ be 
parameterized by rational functions (over an appropriate field). The equation 
becomes a little simpler after completing the square in  T. I don't know if 
you want to think about the processes involved or just the answer. I'll tell 
you what, I'll just paste in the Maple commands I used -- you can ignore 
them or reuse them or think about why they work, as you wish.

F:=(x+y+m1+m2)*(x+y+m1-m2)*(x+y-m1+m2)*(x+y-m1-m2)*
   (x^2-y^2+2*(x+y)*m3+m2^2-m1^2)*(x^2-y^2-2*(x+y)*m3+m2^2-m1^2);
G:=factor(subs({x=(S+T)/2,y=(S-T)/2},F));
T0:=factor(-1/2*coeff(expand(G),T,1)/coeff(expand(G),T,2));
factor(subs(T=T0+T1,G));   
H:=factor(subs(T1=2*m3*T2,"));
#Now we want  z^2=H  ; it's clear that  T2=1, z=0  is one solution. We get all
#the other points by drawing lines through this; the slope is  u=z/(T2-1).
factor(subs({T2=1+t, z=0+u*t}, z^2-H));
tt:=solve("/t,t);
sol1:={z=0+u*tt, T2=1+tt};
sol2:=sol1 union subs(sol1, {T1=2*m3*T2});
sol3:=sol2 union subs(sol2, {T=T0+T1});
sol4:=sol3 union subs(sol3, {x=(S+T)/2,y=(S-T)/2});
best:=factor(subs(sol4,[x,y,z]));
#check it out:
factor(subs({x=best[1],y=best[2]},F));
best[3]^2-";

You can trace back through this to invert the parameterization: of course
S = x+y, and  u  is  2*(x+y)*m3  times the square root of  
(x+y-m1-m2)*(x+y+m1-m2)*(x+y-m1+m2)*(x+y+m1+m2)*
(x^2+2*m3*x+2*m3*y-y^2+m2^2-m1^2)/(-y^2+x^2-m1^2+m2^2-2*m3*x-2*m3*y)

This parameterization is sufficient, but probably not optimal. For
example, I would in retrospect probably replace  u  with  u2=u/2/S/m3.

As far as literature goes, the subject you're looking at here is
"Algebraic geometry". specifically in your case you're asking whether or
not certain affine surfaces in 3-space are rational. You might get some
helpful information from the pages off
	index/14-XX.html

dave