Newsgroups: sci.math
From: pmontgom@cwi.nl (Peter L. Montgomery)
Subject: Re: Galois groups of polynomials
Nntp-Posting-Host: bark.cwi.nl
Date: Sun, 19 Jul 1998 06:12:59 GMT

In article <35acf2a3.6967279@news.belgium.eu.net> bogaerm@gib.be writes:
>Until a little while I was convinced that the galois group of a
>polynomial of degree p was the group S_p of permutations of p elements
>(generally speaking, unless the polynomial was rather "special".
>Somewhere (I lost the reference) I saw that the Galois group of the
>polynomial
>	x^6+2*x^5+3*x^4+4*x^3+5*x^2+6*x+7
>is _not_  S6.
>How can one derive such conclusions ?


#  This is a Maple script, containing information about how this f splits.

f := x^6 + 2*x^5 + 3*x^4 + 4*x^3 + 5*x^2 + 6*x + 7;

#  The discriminant of f is -2^16 * 7^4.
#  This is the negative of a perfect square.
#  Hence sqrt(-1) is in the splitting field.

ifactor(discrim(f, x));   # Negative of perfect square

#     Check how f splits mod p, where p is prime in [1000, 1200].

for p from 1001 to 1199 by 2 do
    if (isprime(p)) then
        print(p, Factor(f) mod p);
    fi;
od;

#      Degrees          Primes

#      1,1,1,1,1,1      1013
#      1,1,2,2          1021, 1049, 1069, 1097, 1109, 1129, 1193
#      1,1,4            1031, 1039, 1051, 1087, 1091, 1123, 1151, 1171
#      1,5              1009, 1033, 1061, 1181
#      2,2,2            1063, 1087
#      3,3              1093, 1117, 1153
#      6                1103, 1163

#      Some degree patterns are missing, notably 2,4 and 1,2,3
#      but also 1,1,1,3 and 1,1,1,1,2.
#      In S6, 90 of the 720 permutations have cycles of lengths
#      2 and 4, and another 90 have cycle lengths 1, 1, 4.
#      Here f splits into factors of degrees 1, 1, 4
#      modulo 8 of 27 primes, but never into 2 and 4.
#      Unless we have encountered a statistical fluke,
#      the Galois group of f is _not_ S6.
#      Nor is it A6, since the discriminant is not a perfect square.
#      According to Maple, it has order 120.

galois(f);

#      If r1 is a root of f, then f(x)/(x - r1) is irreducible
#      over Q(r1) since f splits into degrees 1,5 modulo some primes.
#      Even if we start with two distinct roots r1 and r2 of f,
#      the quotient polynomial f(x)/((x - r1)*(x - r2))
#      remains irreducible over Q(r1, r2) since f sometimes
#      splits into degrees 1,1,4.

#      If we start with three distinct roots r1, r2, r3 of f,
#      then Q(r1, r2, r3) will have degree 6 * 5 * 4 = 120 over Q.
#      If we believe the Galois group has order 120,
#      then Q(r1, r2, r3) must be the splitting field of f.
#      That is, f has six linear factors over Q(r1, r2, r3).
#      To confirm this, I give a fourth root (r4) below.
#      The last roots can be found by permuting r1, r2, r3.
#      I also give an expression for sqrt(-1).

#      Can anyone come up with a more elegant expression for
#      r4 in terms of r1, r2, r3?  Ideally, if this
#      has the form r4 = h(r1, h2, r3), then we can tell by
#      inspection whether r3 = h(r1, r2, r4).


r1poly := subs(x = r1, f);
r2poly := normal((subs(r1 = r2, r1poly) - r1poly)/(r2 - r1));
r3poly := normal((subs(r2 = r3, r2poly) - r2poly)/(r3 - r2));
r4poly := normal((subs(r3 = r4, r3poly) - r3poly)/(r4 - r3));

sym1 := r1 + r2 + r3;
sym2 := r1*r2 + r1*r3 + r2*r3;
sym3 := r1*r2*r3;
sqrtm1 := expand(5 + 7*sym1 - 15*sym1^2 + 27*sym2
           - 11*sym1^3 + 18*sym1*sym2 + 3*sym3
           - 3*sym2^2 - 3*sym2*sym1^2 + 14*sym1*sym3
           - 3*sym2^2*sym1 - 6*sym2*sym3 + 11*sym3*sym1^2
           + 3*sym2^3 + 3*sym3^2- 2*sym1*sym2*sym3
           + 5*sym3*sym2^2 - 3*sym3^2*sym1 + 3*sym3^2*sym2 + 3*sym3^3)/56;
simplify(sqrtm1^2, {r3poly, r2poly, r1poly});    # -1

r4 := (17*r2^3*r1^3+(6*r2^3*r1^3+4*r2^3*r1^2+4*r2^2*r1^3+2*r2^3*r1+6*r2^2*r1
^2+2*r2*r1^3+4*r2^3+4*r1^3-2*r2^2-18*r2*r1-2*r1^2-8*r2-8*r1+6)*r3^5-9*r2^3*r1^
2-9*r2^2*r1^3+(11*r2^3*r1^3+7*r2^3*r1^2+7*r2^2*r1^3+3*r2^3*r1+7*r2^2*r1^2+3*r2
*r1^3+9*r2^3+r2^2*r1+r2*r1^2+9*r1^3+3*r2^2-19*r2*r1+3*r1^2+9*r2+9*r1+21)*r3^4-\
5*r2^3*r1-15*r2^2*r1^2-5*r2*r1^3+(12*r2^3*r1^3+4*r2^3*r1^2+4*r2^2*r1^3+8*r2^2*
r1^2+8*r2^3+4*r2^2*r1+4*r2*r1^2+8*r1^3+8*r2^2-12*r2*r1+8*r1^2+16*r2+16*r1+24)*
r3^3+11*r2^3-13*r2^2*r1-13*r2*r1^2+11*r1^3+(16*r2^3*r1^3+10*r2^3*r1^2+10*r2^2*
r1^3+2*r2^3*r1+20*r2^2*r1^2+2*r2*r1^3+8*r2^3+12*r2^2*r1+12*r2*r1^2+8*r1^3+6*r2
^2-20*r2*r1+6*r1^2+6*r2+6*r1+8)*r3^2-5*r2^2-29*r2*r1-5*r1^2+(22*r2^3*r1^3+12*
r2^3*r1^2+12*r2^2*r1^3-2*r2^3*r1+2*r2^2*r1^2-2*r2*r1^3+16*r2^3-4*r2^2*r1-4*r2*
r1^2+16*r1^3-10*r2^2-42*r2*r1-10*r1^2-6)*r3+5*r2+5*r1-25)/112;

simplify(r4poly, {r3poly, r2poly, r1poly});    # Zero
;quit;

-- 
        Peter-Lawrence.Montgomery@cwi.nl    San Rafael, California